既存AWS構成をOpenTofuでIaC管理できるようにしてみた

こんにちは、AI Labの川口あいです。

本記事では、AWS環境の構成を IaC(Infrastructure as Code)で管理できるようにするプロジェクトに取り組んだ際の内容をまとめます。

対象となったのは、既存のAWS構成に対して監視・バックアップ・証明書管理・静的配信構成などを段階的に追加し、それらを tf ファイルとして再現可能な形へ整理していく作業です。

今回のフェーズでは、主に以下の内容に対応しました。

  • EC2向けCloudWatch Alarmの追加
  • AWS Backupの設定追加
  • Backup結果を監視するCloudWatch Alarmの追加
  • ACM証明書のDNS検証設定
  • S3 + CloudFront による配信構成の追加
  • README / 利用手順ドキュメントの整備

取り組みを通じて、IaCの書き方そのものだけでなく、AWSサービス間の関係、リージョン差異、ローカル検証環境の扱い、ドキュメント整備の重要性 まで含めて多くの学びがありました。

本記事では、実装内容に加えて、作業中に直面した問題や工夫した点についても整理して紹介します。

なお、社外公開向けの記事として、一部のドメイン名・ARN・アカウント情報・ブランチ名などは伏せたうえで記載しています。

目次

プロジェクトの目的

今回の取り組みの目的は、AWS上で手作業または個別スクリプトに依存していた構成を、IaCによって管理しやすい形へ移行していくことでした。

単に tf ファイルを作成するだけでなく、以下のような観点まで含めて整備することが求められていました。

  • apply によって実際にリソースを作成できること
  • LocalStack や AWS 実環境で検証できること
  • 他のメンバーが手順に沿って再現できること
  • 運用時の注意点まで文書化されていること

そのため、今回の作業では「コードを書くこと」そのものよりも、再現性と運用性をどう担保するか が重要なテーマでした。

前提となる技術スタック

今回の構成で使っていた技術スタックは次の通りです。

  • IaC: OpenTofu構成
  • Cloud: AWS
  • ローカル検証: LocalStack
  • 実行環境: Docker / docker compose
  • 実行補助: Makefile
  • 補助ツール: ChatGPT

CloudWatch, AWS Backup, ACM, Route53, S3, CloudFront といった AWSサービスを対象にしつつ、LocalStackで確認できる部分はローカルで回し、最終的なapplyはAWS実環境でも確認する流れでした。README更新タスクでも、make up / init / plan / apply / destroy を起点にした実行フローや、LocalStack向けの補足手順が整理されています。

概要図

今回の実行環境の概要図は以下の通りです。

利用者
make up / make plan / make apply
↓
Makefile
↓
docker-compose.yml
↓
command_runner
OpenTofu / awscli を実行する作業用コンテナ
↓
LocalStack
AWS API をローカルで模擬するコンテナ
↓
./aws
root module + modules
↓
.env
AWS資格情報 / AWS_DEFAULT_REGION
ENVIRONMENT=local →
LocalStack
ENVIRONMENT=prod →
Real AWS
vpc module
subnet module
security module
ec2 module

Makefileを起点にdocker-compose.yml経由でcommand_runnerとLocalStackを起動し、command_runnerからaws/配下のOpenTofu設定を実行します。 実行先はENVIRONMENT=localの場合はLocalStack、ENVIRONMENT=prodの場合は実際のAWSです。

ディレクトリ構造

tofu/
├── Makefile                    # 実行の入口。`make up/init/plan/apply/destroy` などをまとめて呼び出す
├── docker-compose.yml          # `command_runner` と `localstack` を起動するための Compose 定義
├── Dockerfile                  # `command_runner` コンテナの実行環境を構築する定義
├── entrypoint.sh               # `command_runner` 起動時に最初に実行されるスクリプト
├── .env.example                # `.env` 作成用のテンプレート。AWS 認証情報やリージョン設定の雛形
├── README.md                   # AWS 環境向けの利用手順をまとめたドキュメント
├── README_localstack.md        # LocalStack 環境向けの利用手順をまとめたドキュメント
└── aws/                        # OpenTofu の root module 一式。`make plan/apply/destroy` の実行対象
    ├── main.tf                 # 各 module を呼び出して、全体の AWS 構成を組み立てる中心ファイル
    ├── provider.tf             # AWS / LocalStack の接続先や認証方式を切り替える provider 定義
    ├── variables.tf            # root module で受け取る入力変数を定義する
    ├── versions.tf             # OpenTofu / Provider のバージョン制約を定義する
    ├── outputs.tf              # apply 後に確認したい値を出力する定義
    ├── static_var.auto.tfvars  # 常に読み込まれる固定値。AMI、VPC、Subnet などの基本設定を書く
    ├── envs/                   # 必要に応じて `TFVARS=...` で読み込む追加変数ファイル置き場
    │   └── dynamic_var.tfvars  # 環境差分や一時的な上書き値を書く例
    ├── requirements.txt        # `command_runner` 内で使う Python パッケージ定義
    └── modules/                # リソース単位に分割した再利用可能な module 群
        ├── vpc/                # VPC 関連リソースをまとめた module
        │   ├── main.tf         # VPC module の本体。実際のリソース定義を書く
        │   ├── variables.tf    # VPC module に渡す入力変数を定義する
        │   └── outputs.tf      # VPC module から外へ返す出力値を定義する
        ├── ec2/                # EC2 インスタンス関連をまとめた module
        ├── subnet/             # public/private subnet をまとめて管理する module
        ├── security/           # Security Group をまとめて管理する module
        └── ...                 # module はここに追加していく。代表例のみ記載

ポイントは、aws/main.tfから各機能をmodules/以下のmoduleとして呼び出す構成になっていることです。 既存構成に対して機能をそのまま書き足すのではなく、責務ごとにmoduleを追加していく形にしていました。

今回の実装方針

今回は、既存のroot moduleに対して各機能をmoduleとして追加していく構成にしてあります。 例えば、S3+CloudFrontではroot側から次のように呼び出す形です。

module "s3" {
  source      = "./modules/s3"
  bucket_name = var.bucket_name
}

module "cloudfront" {
  source = "./modules/cloudfront"

  s3_bucket_regional_domain_name = module.s3.bucket_regional_domain_name
  s3_bucket_id                   = module.s3.bucket_id
  s3_bucket_arn                  = module.s3.bucket_arn
  index_document                 = var.index_document
  price_class                    = var.price_class
}

S3側のmoduleではバケット自体の作成と、そのバケットを参照するために必要な情報の出力に集中させ、CloudFront側のmoduleでは配信設定をまとめて扱う形にしています。

今回対応した内容

今回のフェーズでは、既存構成に対して以下のmoduleを追加・拡張しました。

  • ec2_status_check_alarms:EC2 のステータスチェック異常を監視する CloudWatch Alarm
  • aws_backup:EC2を対象にしたAWS Backupの設定
  • monitoring_backup:Backup実行結果を監視するCloudWatch Alarm
  • acm:ACM証明書の発行とDNS検証
  • s3 / cloudfront:静的配信構成
  • README / 利用手順まわり:LocalStack / AWS 実行手順の整理

この中でも、今回は特に実装上の工夫やつまずきが大きかった2つをピックアップし、実際のコードを交えながら紹介します。

1. AWS Backup: 変数をそのまま使わず、用途に合わせて整形する

今回のOpenTofu実装では、EC2インスタンス1台を対象に、AWS Backupを使った日次バックアップを自動で作成するmoduleを用意しました。

ファイル構成

tofu/aws/
├── main.tf
├── variables.tf
└── modules/
    └── aws_backup/
        ├── main.tf
        ├── variables.tf
        └── outputs.tf

それぞれの役割は次のとおりです。

  • tofu/aws/main.tf:root module側から aws_backup moduleを呼び出します。
  • tofu/aws/modules/aws_backup/variables.tf:EC2名、EC2インスタンスIDなどの入力値を定義します。
  • tofu/aws/modules/aws_backup/main.tf:Backup Vault、Backup Plan、Backup Selectionを作成する本体です。
  • tofu/aws/modules/aws_backup/outputs.tf:作成したBackup Vault名やBackup Plan IDを出力します。

実装イメージ

root moduleからは、EC2 moduleで作成したインスタンスIDを受け取り、次のようにaws_backup moduleを呼び出しています。

module "aws_backup" {
  source          = "./modules/aws_backup"
  ec2_name_tag    = var.ec2_name_tag
  ec2_instance_id = module.ec2.ec2_instance_id
  kms_key_arn     = null
}

実際の aws_backup moduleのmain.tfでは、バックアップの保存先、実行ルール、対象リソースの関連付けをまとめて定義しています(一部抜粋)。

resource "aws_backup_vault" "ec2" {
  name        = replace(var.ec2_name_tag, ".", "-")
  kms_key_arn = var.kms_key_arn

  tags = {
    Backup-Type = "Auto"
  }
}

resource "aws_backup_plan" "ec2" {
  name = "${sanitized_name}_backup_plan"

  rule {
    rule_name         = "${replace(var.ec2_name_tag, ".", "-")}_DAILY_BACKUP_3GEN_RULE"
    target_vault_name = aws_backup_vault.ec2.name
    schedule = "cron(...)"


    lifecycle {
      delete_after = 3
    }
  }
}

resource "aws_backup_selection" "ec2" {
  iam_role_arn = "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/service-role/AWSBackupDefaultServiceRole"
  name         = "EC2_${replace(var.ec2_name_tag, ".", "-")}"
  plan_id      = aws_backup_plan.ec2.id

  resources = [local.ec2_instance_arn]
}

このmoduleでは、aws_backup_vaultでバックアップの保存先を用意 / aws_backup_planでバックアップの実行ルールを定義 / aws_backup_selectionで対象のEC2インスタンスを関連付けています。

つまづいたポイント

AWS Backupの実装では、バックアップボールト名にEC2の名前をそのまま流用しようとして、一度 plan / apply が止まる場面がありました。
当初は、対象ホスト名として使っていたec2_tag_nameをそのままボールト名に使う形で実装していました。

resource "aws_backup_vault" "ec2" {
  name = var.ec2_tag_name

  tags = {
    Backup-Type = "Auto"
  }
}

しかし、検証時に ec2_tag_name として使っていた値には . が含まれており、そのままではバックアップボールト名として扱えず、エラーになっていました。

そこで、最終的にはバックアップボールト名をそのまま流用するのではなく、replace()を使って. を -に置き換えるように修正しました。

resource "aws_backup_vault" "ec2" {
  # ドットをハイフンに変換
  name = replace(var.ec2_tag_name, ".", "-")

  tags = {
    Backup-Type = "Auto"
  }
}

この変更によって、EC2側ではそのまま扱えていた名前を、AWS Backup側でも利用できる形式に揃えられるようになりました。

2. CloudWatch Alarm: Terraformのコードだけでなく、LocalStack側の設定も揃える

今回のOpenTofu実装では、EC2インスタンス1台を対象に、EC2のステータスチェック異常をCloudWatch Alarmで監視するec2_status_check_alarms moduleを追加しました。

このmoduleでは、EC2で発生する2種類のステータスチェック異常を検知します。 1つはインスタンスOS側の異常を表すStatusCheckFailed_Instance、もう1つはホスト基盤側の異常を表すStatusCheckFailed_Systemです。 異常を検知した際はSNSへ通知し、さらにシステムステータス異常についてはEC2の自動復旧も実行できるようにしています。

ファイル構成

tofu/aws/
├── main.tf
├── variables.tf
└── modules/
    └── ec2_status_check_alarms/
        ├── main.tf
        └── variables.tf

それぞれの役割は次のとおりです。

  • tofu/aws/main.tf:root module側からec2_status_check_alarms moduleを呼び出します。
  • tofu/aws/variables.tf:root moduleで受け取るsns_arnなどの入力値を定義します。
  • tofu/aws/modules/ec2_status_check_alarms/variables.tf:監視対象のEC2インスタンスID、EC2名、通知先SNS ARNをmoduleの入力値として定義します。
  • tofu/aws/modules/ec2_status_check_alarms/main.tf:CloudWatch Alarmを2つ作成する本体です。インスタンスステータス異常の監視用Alarmと、システムステータス異常の監視+自動復旧用Alarmを定義しています。

実装イメージ

root moduleからは、EC2 moduleで作成したインスタンスIDを受け取り、次のようにec2_status_check_alarms moduleを呼び出しています。

module "ec2_status_check_alarms" {
  source = "./modules/ec2_status_check_alarms"

  ec2_instance_id = module.ec2.ec2_instance_id
  ec2_name_tag    = var.ec2_name_tag
  sns_arn         = var.sns_arn
}

実際のec2_status_check_alarms moduleのmain.tfのポイントになる部分を抜粋すると次のような形です。

resource "aws_cloudwatch_metric_alarm" "check_status_instance" {
  alarm_name  = "EC2 ${var.ec2_name_tag} CheckStatus"
  metric_name = "StatusCheckFailed_Instance"
  namespace   = "AWS/EC2"
  statistic   = "Average"
  period      = 300
  threshold   = 1

  dimensions = {
    InstanceId = var.ec2_instance_id
  }

  evaluation_periods  = 2
  datapoints_to_alarm = 2

  alarm_actions = [var.sns_arn]
}

このAlarmでは、StatusCheckFailed_Instance を監視しています。 EC2インスタンス側で異常が発生した場合に、SNSへ通知する構成です。

さらに、システムステータス異常に対しては、通知だけでなく自動復旧も行うようにしています。

resource "aws_cloudwatch_metric_alarm" "check_status_and_recovery" {
  alarm_name  = "EC2 ${var.ec2_name_tag} CheckStatusAndRecovery"
  metric_name = "StatusCheckFailed_System"
  namespace   = "AWS/EC2"
  statistic   = "Average"
  period      = 300
  threshold   = 1

  dimensions = {
    InstanceId = var.ec2_instance_id
  }

  evaluation_periods  = 2
  datapoints_to_alarm = 2

  alarm_actions = [
    var.sns_arn,
    "arn:aws:automate:<region>:ec2:recover"
  ]
}

こちらは StatusCheckFailed_Systemを監視するAlarmです。 AWS基盤側の異常を検知した場合に、SNS通知に加えてec2:recoverを実行し、EC2の自動復旧を試みる構成にしています。

つまづいたポイント

CloudWatch AlarmのOpenTofuコード自体は、既存の監視条件をaws_cloudwatch_metric_alarmに落とし込んでいく形だったため、実装の方向性は比較的見えやすい部分でした。

しかし、LocalStack上でtofu applyを実行すると、CloudWatch Alarm作成時にエラーになりました。 原因はOpenTofuのコードそのものではなく、LocalStack側でcloudwatchサービスが有効になっていなかったことです。

つまり、aws_cloudwatch_metric_alarmを書いていても、ローカル検証環境でCloudWatchが起動していなければAPIは受け付けられません。

修正した内容

この問題に対しては、Terraform側のprovider endpointと、LocalStack側のSERVICESの両方にcloudwatchを追加しました。

まず、provider.tf側ではLocalStack用endpointにCloudWatchを含めます(一部抜粋)。

provider "aws" {
  region = var.aws_region

  access_key                  = var.environment == "local" ? "test" : null
  secret_key                  = var.environment == "local" ? "test" : null
  skip_credentials_validation = var.environment == "local"
  skip_metadata_api_check     = var.environment == "local"
  skip_requesting_account_id  = var.environment == "local"
  s3_use_path_style           = var.environment == "local"

  dynamic "endpoints" {
    for_each = var.environment == "local" ? [1] : []
    content {
      ec2        = var.localstack_endpoint
      cloudwatch = var.localstack_endpoint
    }
  }
}

合わせて、docker-compose.yml側でもCloudWatchを有効化します(一部抜粋)。

environment:
  - SERVICES=s3,ec2,cloudwatch
  - DEBUG=1
  - DATA_DIR=/tmp/localstack/data

これによって、LocalStack上でもCloudWatch Alarmの作成が通るようになり、describe-alarmsでもアラームが確認できる状態になりました。

つまり、LocalStackを使う場合は、

  • Terraform側でそのサービスのendpointを追加する
  • LocalStack側でそのサービス自体を有効化する

という2つをセットで揃える必要があります。

README整備の重要性を実感した話

今回の取り組みの中で、想像以上に重要だったのがREADMEや利用手順書の整備です。

実装作業の一部というより補足的な作業に見えがちですが、実際には再現性や安全性に大きく関わるものでした。

改善した主な内容

  • tofu ディレクトリ直下でコマンドを実行することを明記
  • LocalStack用とAWS用で必要な設定を分けて説明
  • AWS_DEFAULT_REGION を明示する
  • LocalStackでは事前にダミーAMIを作成する手順を追加
  • エラー発生時にどこまで手順を戻すべきかを整理
  • destroy実行時の注意点やstateファイルに関する説明を追加

苦戦した点

コードが正しくても、環境構築手順が曖昧だと再現できないという問題が何度もありました。

たとえば、

  • 実行ディレクトリが異なることでmakeコマンドが失敗する
  • リージョン未設定により想定外の動作になる
  • LocalStack環境で必要な準備が不足し、planが途中で止まる

といった問題は、コードだけでは防げません。

LocalStackを使った検証で分かったこと

今回の構成ではLocalStackも活用しましたが、単にmake upして終わりではなく、事前に揃えておくべき設定がいくつかありました。 特に、LocalStackではダミーAMIを事前に作成しておかないとplanが失敗するケースもあり、READMEにはその準備手順も含めて整理しました。

このあたりはコード本体ではありませんが、再現性のある構成として扱うためには重要な部分でした。

ChatGPTをどのように活用したか

今回の実装ではChatGPTのCodex(GPT-5.4)も補助的に使いました。

使い方としては、完成コードをそのまま出す用途というより、次のような場面で活用しました。

  • AWS サービス間の関係整理
  • Terraform / OpenTofu の記述パターンのたたき台作成
  • エラー原因の切り分け観点の整理
  • READMEの下書き作成

特に、AWS BackupやACMのように「どのリソースがどうつながるか」を整理したいときに有効でした。 一方で、最終的な構成や設定値の妥当性は必ず自分で確認する前提で進めています。

まとめ

本記事では、既存の AWS 構成に対して OpenTofu を用いて機能を段階的に追加し、modules/ を中心とした構成で管理していった内容をまとめました。

今回対応した内容は、CloudWatch Alarm、AWS Backup、Backup結果監視、ACM、S3 + CloudFront、README整備と多岐にわたりますが、実装を通して特に重要だと感じたのは次の3点です。

  • module の責務を明確に分けること
  • 変数をそのまま流用せず、利用先に合わせて整形すること
  • Terraform / OpenTofu のコードだけでなく、検証環境側の設定もあわせて整えること

今回の実装を通じて、IaC は単に AWS リソースをコード化する作業ではなく、

  • どの単位でmoduleを分けるか
  • module間でどの値を受け渡すか
  • 入力値をどこで整形するか
  • どの環境でどこまで検証するか
  • 他の人が再現できる手順としてどう残すか

まで含めて設計することが重要だと学びました。

特に、READMEやLocalStack向け手順の整備は、コード本体とは別の作業に見えて、実際には再現性を支える重要な要素でした。
make up / init / plan / apply / destroy の流れを安定して実行できるようにするには、実行ディレクトリ、リージョン設定、ダミー AMI の準備など、周辺の前提条件まで含めて整理しておく必要があります。

今後は、今回作成した構成をさらに改善しながら、

  • moduleの粒度や責務分離の見直し
  • LocalStackと実AWS環境での検証手順の整理
  • 運用手順の継続的な改善
  • 監視や配信構成の運用確認

といった点にも取り組んでいきたいと考えています。

​

​